Modelowanie parametryczne
Naprężenia
zredukowane wg Hubera, h×b=80×60 mm
Naprężenia
zredukowane wg Hubera, taki sam przekrój (ciężar) 4800 [mm^2]
h×b=100×48 [mm]
Naprężenia
zredukowane wg Hubera, taki sam przekrój (ciężar) 4800 [mm^2]
h×b=120×40 [mm]
Naprężenia
zredukowane wg Hubera, taki sam przekrój (ciężar) 4800 [mm^2]
h×b=60×80 [mm]
Ułatwienie badania modelu: modelowanie parametryczne
dowolna wartość liczbowa może być opisana nie liczbą, a symbolicznym parametrem
np. geometria_3.mac
/PREP7
!pierwsza warstwa k-pointów
K, 1,-925,0
K, 2,-800,0
K, 3,-700,0
K, 4, -40,0
K, 5, -25,0
K, 6, -10,0
K, 7, 10,0
K, 8, 25,0
K, 9, 40,0
K,10, -10,10
K,11, 10,10
K,12,-17.68,17.68
K,13, 17.68,17.68
K,14, 40,h/2
K,15, -40,h/2
K,16,-700,h/2
K,17,-700-r,65
K,18,-925,65
!druga warstwa k-pointów
K,101,-925, 0,-b
K,102,-800, 0,-b
K,103,-700, 0,-b
K,104, -40, 0,-b
K,105, -25, 0,-b
K,106, -10, 0,-b
K,107, 10, 0,-b
K,108, 25, 0,-b
K,109, 40, 0,-b
K,110, -10, 10,-b
K,111, 10, 10,-b
K,112,-17.68,17.68,-b
K,113, 17.68,17.68,-b
K,114, 40, h/2,-b
K,115, -40, h/2,-b
K,116,-700, h/2,-b
K,117,-700-r, 65,-b
K,118,-925, 65,-b
!trzecia wartwa k-pointów
K,205, -25, 0,-b-200
K,206, -10, 0,-b-200
K,207, 10, 0,-b-200
K,208, 25, 0,-b-200
K,210, -10, 10,-b-200
K,211, 10, 10,-b-200
K,212,-17.68,17.68,-b-200
K,213, 17.68,17.68,-b-200
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!! bryły w sposób systematyczny
L,1,2 !L1
L,2,17 !L2
L,17,18 !L3
L,18,1 !L4
L,101,102 !L5
L,102,117 !L6
L,117,118 !L7
L,118,101 !L8
!prostop.
L,1,101 !L9
L,2,102 !L10
L,17,117 !L11
L,18,118 !L12
AL,1,2,3,4 !A1
AL,5,6,7,8 !A2
AL,1,10,5,9 !A3
AL,2,10,6,11 !A4
AL,3,11,7,12 !A5
AL,4,9,8,12 !A6
VA,1,2,3,4,5,6 !V1
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!! bryły "na skróty"
LARC,16,17,2,-r
LARC,5,12,6,25
LARC,12,13,6,25
LARC,13,8,7,25
LARC,116,117,102,-r
LARC,105,112,106,25
LARC,112,113,106,25
LARC,113,108,107,25
V,2,3,16,17,102,103,116,117
V,3,4,15,16,103,104,115,116
V,4,5,12,15,104,105,112,115
V,5,6,10,12,105,106,110,112
V,6,7,11,10,106,107,111,110
V,7,8,13,11,107,108,113,111
V,8,9,14,13,108,109,114,113
V,10,11,13,12,110,111,113,112
V,12,13,14,15,112,113,114,115
!oś
LARC,205,212,206,25
LARC,212,213,206,25
LARC,213,208,207,25
V,105,106,110,112,205,206,210,212
V,106,107,111,110,206,207,211,210
V,107,108,113,111,207,208,213,211
V,110,111,113,112,210,211,213,212
VSYMM,Y,ALL
NUMMRG,KP
FINISH
ale wcześniej należy zdefiniować te parametry (plik parametry.mac):
h=104 !nazwa
zmiennej: dowolny zestaw liter i cyfr, zaczynający się od
litery
a=80*60
b=a/h
r=(130-h)/2
ANSYS Parametric Design Language (APDL)
wyrażenia:
+ dodawanie: a=b+c
- odejmowanie: a=b-c
* mnożenie: a=b*c
/ dzielenie: a=b/c
**podnoszenie do potęgi: a=b**c
funkcje:
ABS(x) - wartość bezwzględna |x|
SIGN(x,y) - wartość bezwzględna z z ze
znakiem odziedziczonym po y, (y=0 daje wynik dodatni)
EXP(x) - e do potęgi x
LOG(x) - logarytm naturalny z x ln(x)
LOG10(x) - logarytm dziesiętny z x log10(x)
SQRT(x) - pierwiastek kwadratowy z x
NINT(x) - zaokrąglenie x do liczby
całkowitej
MOD(x,y) - część ułamkowa x/y,
obliczana jako x - (INT(x/y) * y), y=0 zwraca zero (0).
RAND(x,y) - liczba losowa (wg rozkładu
równomiernego) w zakresie (x,y)
GDIS(x,y) - liczba losowa (wg rozkładu
normalnego) o średniej x i odchyleniu standard. y
SIN(x),
COS(x), TAN(x)
- funkcje trygonometryczne, argument domyślnie w radianach, co
można zmienić na stopnie za pomocą funkcji *AFUN
SINH(x),
COSH(x), TANH(x)
- funkcje hiperboliczne
ASIN(x),
ACOS(x), ATAN(x)
- odwrotne funkcje trygonometryczne, x pomiędzy -1 i 1, wynik
domyślnie w radianach, co można zmienić na stopnie za pomocą
funkcji *AFUN,
ATAN2(y,x) - arcus tangens x/y z
uwzględnieniem znaków obu liczb, *AFUN też działa
poza tym APDL posiada możliwości programowania strukturalnego FORTRANU
przykład:
zamiast pliku w_3.mac plik petla.mac, automatycznie
zmieniajcy wartości parametrów, wykonujący obliczenia i
zapisujący wyniki do pliku
(optymalizacja!)
*DO,i,0,30 ! For I = 1 to 30:
/PREP7
ALLSEL
VCLEAR,ALL !usuwa wszystkie elementy i węzły z zaznaczonych brył
VDELE,ALL
ADELE,ALL
LDELE,ALL
KDELE,ALL
FINISH
h=i*2+60 !nowe definiowanie parametrów
a=80*60
b=a/h
r=(130-h)/2
geometria_3
elementy
podparcie_3
obciazenie
obliczenia
ogladanie
*GET,napr_Hubera,PLNSOL
/OUTPUT,wyniki,prn,,APPEND
!/COM,h %h%, naprezenia Hubera %napr_Hubera% !przykład zapisu do pliku z komentarzem
!/COM !"pusty wiersz"
/COM, %h% %napr_Hubera% !h - to nazwa pierwszego zapisywanego parametru, napr_Hubera - drugiego
/OUTPUT
*ENDDO
Wyniki obliczeń petla.mac
plik wyniki.prn
60 237.366272
62 234.346939
64 231.439011
66 228.634598
68 225.92543
70 188.13501
72 185.246887
74 182.541138
76 179.954681
78 177.559158
80 175.138535
82 173.133057
84 175.48793
86 174.786133
88 173.233276
90 171.839188
92 160.571136
94 159.261124
96 158.213989
98 157.458298
100 160.271103
102 141.007935
104 138.140625
106 141.670685
108 145.680222
110 149.638474
112 158.083801
114 161.958145
116 165.737823
118 169.404602
120 172.941162
plik wczytany w
MathCadzie:
Rozwiązanie
optymalne
parametry można także czytać bezpośrednio w ANSYSie:
nieparametryczny |
parametryczny prosty |
parametryczny wyrafinowany |
model geometryczny | ||
podział na elementy | taki sam |
taki sam |
model podparcia | taki sam jak w prostym |
|
model obciążenia | taki sam |
taki sam |
taki sam |
taki sam |
|
taki sam |
taki sam |
|
taki sam |
taki sam |
|
plik badający wpływ wskazanego parametru na naprężenia - petla.mac